speaker-confusion-model/code/models/enumeration.stan

functions {
    real confusion_model_lpmf(array[] int group,
        int start, int end,
        int n_classes,
        array[,] int vtc,
        array[,] int truth,
        array[] real clip_duration,
        array[] matrix lambda,
        array[] vector lambda_fp
    ) {
        real ll = 0;
        vector [4] bp;
        vector [4] log_lik;

        vector[16384] log_contrib_comb;
        int n = size(log_contrib_comb);

        for (k in start:end) {
            log_lik = rep_vector(0, 4);
            for (i in 1:n_classes) {
                log_contrib_comb[:n] = rep_vector(0, n);
                n = 1;

                for (chi in 0:truth[k,1]) {
                    bp[1] = binomial_lpmf(chi | truth[k,1], lambda[group[k-start+1],1,i]);
                    for (och in 0:truth[k,2]) {
                        bp[2] = binomial_lpmf(och | truth[k,2], lambda[group[k-start+1],2,i]);
                        for (fem in 0:truth[k,3]) {
                            bp[3] = binomial_lpmf(fem | truth[k,3], lambda[group[k-start+1],3,i]);
                            for (mal in 0:truth[k, 4]) {
                                bp[4] = binomial_lpmf(mal | truth[k,4], lambda[group[k-start+1],4,i]);
                                int delta = vtc[k,i] - (mal+fem+och+chi);
                                if (delta >= 0) {
                                    log_contrib_comb[n] += sum(bp);
                                    log_contrib_comb[n] += poisson_lpmf(
                                        delta | lambda_fp[group[k-start+1],i]*clip_duration[k]
                                    );
                                    n = n+1;
                                }
                            }
                        }
                    }
                }
                if (n>1) {
                    log_lik[i] = log_sum_exp(log_contrib_comb[1:n-1]);
                }
            }
            ll += log_sum_exp(log_lik);
        }
        return ll;
    }

    real model_lpmf(array[] int children,
        int start, int end,
        int n_recs,
        int n_classes,
        real duration,
        array [,] int vocs,
        matrix truth_vocs,
        array [] matrix actual_confusion,
        array [] vector actual_fp_rate
        ) {
            real ll = 0;

            vector [4] expect;
            //vector [4] sd;

            for (k in start:end) {
                expect = rep_vector(0, 4);
                //sd = rep_vector(0, 4);

                for (i in 1:n_classes) {
                    expect[i] = dot_product(truth_vocs[k,:], actual_confusion[k,:,i]);
                    expect[i] += actual_fp_rate[k,i] * duration;
                }
                
                ll += normal_lpdf(vocs[k,:] | expect, sqrt(expect));
            }

            return ll;
        }
}

// TODO
// use speech rates to set priors on truth_vocs
data {
    int<lower=1> n_classes; // number of classes

    // analysis data block
    int<lower=1> n_recs;
    int<lower=1> n_children;

    array[n_recs] int<lower=1> children;
    array[n_recs] real<lower=1> age;
    array[n_recs, n_classes] int<lower=0> vocs;
    array[n_children] int<lower=1> corpus;

    real<lower=0> recs_duration;

    // speaker confusion data block
    int<lower=1> n_clips;   // number of clips
    int<lower=1> n_groups; // number of groups
    int<lower=1> n_corpora;
    array [n_clips] int group;
    array [n_clips] int conf_corpus;
    array [n_clips,n_classes] int<lower=0> vtc_total; // vtc vocs attributed to specific speakers
    array [n_clips,n_classes] int<lower=0> truth_total;
    array [n_clips] real<lower=0> clip_duration;

    int<lower=1> n_validation;

    // actual speech rates
    int<lower=1> n_rates;
    array [n_rates,n_classes] int<lower=0> speech_rates;
    array [n_rates] int group_corpus;
    array [n_rates] real<lower=0> durations;
}

parameters {
    matrix<lower=0> [n_recs, n_classes] truth_vocs;
    //array [n_children] matrix<lower=0>[n_classes,n_classes] actual_confusion_baseline;
    array [n_recs] matrix<lower=0,upper=1>[n_classes,n_classes] actual_confusion_baseline;
    array [n_recs] vector<lower=0>[n_classes] actual_fp_rate;

    // confusion parameters
    matrix<lower=1>[n_classes,n_classes] etas;
    matrix<lower=0,upper=1>[n_classes,n_classes] mus;
    array [n_groups] matrix<lower=0,upper=1>[n_classes,n_classes] lambda;


    vector<lower=1>[n_classes] alphas_fp;
    vector<lower=0>[n_classes] mus_fp;
    array [n_groups] vector<lower=0>[n_classes] lambda_fp;

    //array [n_corpora] matrix[n_classes,n_classes] corpus_bias;
    //matrix<lower=0>[n_classes,n_classes] corpus_sigma;

    // speech rates
    matrix<lower=1>[n_classes,n_corpora] speech_rate_alpha;
    matrix<lower=0>[n_classes,n_corpora] speech_rate_mu;
    matrix<lower=0> [n_classes,n_rates] speech_rate;
}

transformed parameters {

    // array [n_children] matrix<lower=0,upper=1>[n_classes,n_classes] actual_confusion;

    // for (c in 1:n_children) {
    //     actual_confusion[c] = inv_logit(logit(actual_confusion_baseline[c])+corpus_bias[corpus[c]]);
    // }
}

model {
    //actual model

    //target += reduce_sum(
    //   model_lpmf, children, 1,
    //   n_recs, n_classes, recs_duration,
    //   vocs,
    //   truth_vocs, actual_confusion_baseline, actual_fp_rate
    //);

    for (k in 1:n_recs) {
        for (i in 1:n_classes) {
            actual_confusion_baseline[k,i] ~ beta_proportion(mus[i,:], etas[i,:]);
        }
        actual_fp_rate[k] ~ gamma(alphas_fp, alphas_fp./mus_fp);
    }
    

    for (k in 1:n_recs) {
        truth_vocs[k,:] ~ gamma(
            speech_rate_alpha[:,corpus[children[k]]],
            (speech_rate_alpha[:,corpus[children[k]]]./speech_rate_mu[:,corpus[children[k]]])/1000/recs_duration
        );
    }

    target += reduce_sum(
        confusion_model_lpmf, group, n_clips%/%640,
        n_classes,
        vtc_total, truth_total, clip_duration,
        lambda, lambda_fp
    );

    mus_fp ~ exponential(1);
    alphas_fp ~ normal(1, 1);

    for (i in 1:n_classes) {
        lambda_fp[:,i] ~ gamma(alphas_fp[i], alphas_fp[i]/mus_fp[i]);
        
        for (j in 1:n_classes) {
            if (i==j) {
                mus[i,j] ~ beta(2,1);
            }
            else {
                mus[i,j] ~ beta(1,2);
            }
            etas[i,j] ~ pareto(1, 1.5);
            for (c in 1:n_groups) {
                lambda[c,i,j] ~ beta_proportion(mus[i,j],etas[i,j]);
            }
        }
    }

    // speech rates
    for (i in 1:n_classes) {
        speech_rate_alpha[i,:] ~ normal(1, 1);
        speech_rate_mu[i,:] ~ exponential(2);
    }

    for (g in 1:n_rates) {
        for (i in 1:n_classes) {
            speech_rate[i,g] ~ gamma(
                speech_rate_alpha[i,group_corpus[g]],
                (speech_rate_alpha[i,group_corpus[g]]/speech_rate_mu[i,group_corpus[g]])/1000
            );
            speech_rates[g,i] ~ poisson(speech_rate[i,g]*durations[g]);
        }
    }
}