afni_ci_test_data/retro_ts/run.rts.loop

set eorig = ECG_epiRTslt_scan_4.1D
set rorig = Resp_epiRTslt_scan_4.1D
set odir  = many.tests
set nmax  = 100

# choose whether to test with dylan's update
if ( 0 ) then
   set odir  = $odir.dylan
   set path = ( `pwd`/jz.dylan $path )
   rehash
endif

echo using: `which RetroTS.py`

# make clean output directory
rm -fr $odir
mkdir $odir
cd $odir

# note base file names or prefixes
set ebase = e.15000.1D
set rbase = r.15000.1D
set epre = t.e
set rpre = t.r

# start with input having length % 100 == 0
head -n 15000 ../$eorig > $ebase
head -n 15000 ../$rorig > $rbase

# add 0..199 (nah, 200) lines of zeros to see:
#   1. how the number of lines changes
#   2. are there the same errors for line counts mod 100

foreach ind ( `count -digits 3 0 $nmax` )
   set efile = $epre.$ind.1D
   set rfile = $rpre.$ind.1D
   set lfile = out.rts.$ind

   cp $ebase $efile
   cp $rbase $rfile

   if ( $ind > 0 ) then
      1deval -num $ind -expr 0 >> $efile
      1deval -num $ind -expr 0 >> $rfile
   endif

   set cmd = (RetroTS.py -c $efile -r $rfile -v 2 -p 50 -n 10 -prefix rts.$ind)
   echo $cmd | tee $lfile

   $cmd >>& $lfile
end

echo ""
foreach rfile ( rts.*.1D)
   echo $rfile : `1d_tool.py -infile $rfile -show_rows_cols`
end
echo ""