afni_ci_test_data/ptaylor_shell_tests.tcsh

#!/bin/tcsh

# NB: all parameters in this file are set for testing purposes (=
# brevity, in most case).  These are NOT meant to be realistic use
# cases in practice!


set here    = ${PWD}
set fatdir  = AFNI_demos/FATCAT_DEMO
set dir2    = test_extra
set fatdir2 = ${fatdir}/${dir2}

set mainpref  = "$1"

if ( "${mainpref}" == "" ) then
    set mainpref = RUN_00
endif

set otext  = ${here}/o.status_failures_ptaylor.txt

# -------------------------------------------------------------------------

# Preliminary: check that supplement dir exists

if ( ! -e ${fatdir2} ) then
    echo "** To run these tests you need a supplementary dir in the"
    echo "   FATCAT_DEMO directory, called: ${dir2}"
    exit 1
endif

# -------------------------------------------------------------------------

\mkdir -p ${mainpref}

# want absolute path to dir of test outputs
cd ${mainpref} 
set testdir = ${PWD}
cd -

printf "" > ${otext}

cd ${fatdir}

# -------------------------------------------------------------------------
# -------------------------------------------------------------------------

set prog  = 3ddot_beta
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -input   SOME_ICA_NETS_in_DWI+orig.HEAD                  \
    -mask    mask_DWI+orig.HEAD                              \
    -doeta2                                                  \
    -prefix  ${opref}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# output file will be:  ${opref}_eta2.dat

# -------------------------------------------------------------------------

set prog  = 1dDW_Grad_o_Mat++
set opref = ${testdir}/o.${prog}
set ombat = ${opref}_BMAT.txt
set ocvec = ${opref}_cvec_n-1.txt

echo "++ test-run: ${prog}"

# For 3dDWItoDT
${prog}                                                      \
    -echo_edu                                                \
    -in_row_vec    bvec'[2..32]'                             \
    -in_bvals      bval'[2..32]'                             \
    -flip_y                                                  \
    -out_col_matA  ${ombat}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# for the 3dDTtoNoisyDWI; has N-1 (no '0', sigh)
${prog}                                                      \
    -echo_edu                                                \
    -in_row_vec    bvec'[3..32]'                             \
    -flip_y                                                  \
    -out_col_vec   ${ocvec}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dDWItoDT
set opref = ${testdir}/o.${prog}

# just using '-linear' for speed!

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -prefix       ${opref}                                   \
    -mask         mask_DWI+orig.HEAD                         \
    -eigs                                                    \
    -scale_out_1000                                          \
    -sep_dsets                                               \
    -linear                                                  \
    -bmatrix_FULL ${dir2}/grad_BMAT.txt                      \
    AVEB0_DWI.nii.gz   

if ( ${status} ) printf "${prog}\n" >> ${otext}

# produces several dsets:  ${odti}_{FA,MD,V1,V2,.....}+orig.HEAD

# -------------------------------------------------------------------------

set prog  = 3dROIMaker
set opref = ${testdir}/o.${prog}

# just using '-linear' for speed!

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -nifti                                                   \
    -inset    SOME_ICA_NETS_in_DWI+orig.HEAD                 \
    -thresh   3.0                                            \
    -volthr   130                                            \
    -inflate  2                                              \
    -wm_skel  ${dir2}/DT_FA+orig.HEAD                        \
    -skel_thr 0.2                                            \
    -skel_stop                                               \
    -mask     mask_DWI+orig.HEAD                             \
    -prefix   ${opref}                                       \
    -overwrite

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dDTtoNoisyDWI
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -choose_seed 7                                           \
    -dt_in     ${dir2}/DT_DT+orig.HEAD                       \
    -mask      mask_DWI+orig.HEAD                            \
    -grads     ${dir2}/grad_cvec_n-1.txt                     \
    -noise_DWI 0.05                                          \
    -noise_B0  0                                             \
    -prefix    ${opref}.nii.gz

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dEigsToDT
set opref = ${testdir}/o.${prog}
set odt2  = ${opref}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -eig_vals "${dir2}/DT_L*"                                \
    -eig_vecs "${dir2}/DT_V*"                                \
    -prefix   ${odt2}

# -------------------------------------------------------------------------

set prog  = 3dVecRGB_to_HSL
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -in_vec    ${dir2}/DT_V1+orig.HEAD                       \
    -in_scal   ${dir2}/DT_FA+orig.HEAD                       \
    -mask      mask_DWI+orig.HEAD                            \
    -prefix    ${opref}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dTORTOISEtoHere
set opref = ${testdir}/o.${prog}
set odtT  = ${opref}_PREP.nii.gz

echo "++ test-run: ${prog}"

# first, make a DT copy in the TORTOISE style
3dTcat                                                       \
    -echo_edu                                                \
    -prefix  ${odtT}                                         \
    ${dir2}/DT_DT+orig.HEAD'[0,2,5,1,3,4]' 

${prog}                                                      \
    -echo_edu                                                \
    -dt_tort  ${odtT}                                        \
    -prefix   ${opref}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dDWUncert
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

# run in prep for PROB tracking    
${prog}                                                       \
    -echo_edu                                                 \
    -inset            AVEB0_DWI.nii.gz                        \
    -mask             mask_DWI+orig.HEAD                      \
    -pt_choose_seed   5                                       \
    -prefix           ${opref}                                \
    -input            ${dir2}/DT                              \
    -bmatrix_FULL     ${dir2}/grad_BMAT.txt                   \
    -iters            10
                
if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dTrackID
set opref = ${testdir}/o.${prog}
set otrdet = ${opref}_DET
set otrpr  = ${opref}_PROB

echo "++ test-run: ${prog}"

# WB DET tracking 
${prog}                                                      \
    -echo_edu                                                \
    -mode            DET                                     \
    -dti_in          ${dir2}/DT                              \
    -netrois         mask_DWI+orig.HEAD                      \
    -logic           OR                                      \
    -alg_Thresh_Len  30                                      \
    -alg_Nseed_X     1                                       \
    -alg_Nseed_Y     1                                       \
    -alg_Nseed_Z     1                                       \
    -prefix          ${otrdet}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# network PROB tracking; depends on ROI ICMAP_GMI being created
${prog}                                                       \
    -echo_edu                                                 \
    -mode             PROB                                    \
    -choose_seed      5                                       \
    -no_indipair_out                                          \
    -nifti                                                    \
    -dti_in           ${dir2}/DT                              \
    -uncert           ${dir2}/o.UNCERT+orig.HEAD              \
    -netrois          ${dir2}/ROI_ICMAP_GMI+orig.HEAD         \
    -mask             mask_DWI+orig.HEAD                      \
    -alg_Thresh_Frac  0.2                                     \
    -alg_Nseed_Vox    5                                       \
    -alg_Nmonte       5                                       \
    -dump_rois        AFNI                                    \
    -prefix           ${otrpr}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dNetCorr
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -inset    REST_in_DWI.nii.gz'[5..50]'                    \
    -in_rois  ${dir2}/ROI_ICMAP_GM+orig.HEAD                 \
    -prefix   ${opref}                                       \
    -fish_z                                                  \
    -ts_wb_Z                                                 \
    -nifti                                                   \
    -ts_out 

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dMatch
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -only_dice_thr                                           \
    -inset    SOME_ICA_NETS_in_DWI+orig.HEAD                 \
    -refset   MULTISITE_in_DWI+orig.HEAD                     \
    -mask     mask_DWI+orig.HEAD                             \
    -in_min   1.0                                            \
    -ref_min  3                                              \
    -prefix   ${opref}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dRSFC
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -input      REST_in_DWI.nii.gz'[5..100]'                 \
    -prefix     ${opref}                                     \
    -mask       mask_DWI+orig.HEAD                           \
    -band       0.01 0.1

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dLombScargle
set opref = ${testdir}/o.${prog}
set olsamp = ${opref}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -nifti                                                   \
    -inset      REST_in_DWI.nii.gz'[5..100]'                 \
    -prefix     ${opref}                                     \
    -mask       mask_DWI+orig.HEAD                           \
    -censor_str '[0..3,5,6..18,22..34,36..47,49,51..60,63..84,86..88,90,92..$]'

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dAmpToRSFC
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -nifti                                                   \
    -band    0.01 0.1                                        \
    -mask    mask_DWI+orig.HEAD                              \
    -in_amp  ${dir2}/o.3dLombScargle_amp.nii.gz              \
    -prefix  ${opref}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dClusterize
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -mask          mask_DWI+orig.HEAD                        \
    -inset         SOME_ICA_NETS_in_DWI+orig.HEAD            \
    -ithr          0                                         \
    -idat          0                                         \
    -bisided       -3 3                                      \
    -NN            2                                         \
    -clust_nvox    200                                       \
    -pref_map      ${opref}_MAP.nii.gz                       \
    -pref_dat      ${opref}_DAT.nii.gz                       \
    >              ${opref}_REP.txt

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dReHo
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -mask          mask_DWI+orig.HEAD                        \
    -inset         REST_in_DWI.nii.gz'[5..50]'               \
    -nneigh        7                                         \
    -prefix        ${opref}                                  \
    
if ( ${status} ) printf "${prog}\n" >> ${otext}

# check with ROIs (and different kind of neighborhood opts); depends
# on 3dROIMaker output, above
${prog}                                                      \
    -echo_edu                                                \
    -mask          mask_DWI+orig.HEAD                        \
    -inset         REST_in_DWI.nii.gz'[5..50]'               \
    -box_X         2                                         \
    -box_Y         2                                         \
    -box_Z         3                                         \
    -prefix        ${opref}_ROI                              \
    -in_rois       ${dir2}/ROI_ICMAP_GM+orig.HEAD

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dSliceNDice
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

# make masks
3dcalc                                                       \
    -echo_edu                                                \
    -a       SOME_ICA_NETS_in_DWI+orig.HEAD'[0]'             \
    -b       mask_DWI+orig.HEAD                              \
    -expr    'step(b)*(step(a-3)+step(-3-a))'                \
    -prefix  ${opref}_preA.nii.gz
3dcalc                                                       \
    -echo_edu                                                \
    -a       SOME_ICA_NETS_in_DWI+orig.HEAD'[1]'             \
    -b       mask_DWI+orig.HEAD                              \
    -expr    'step(b)*(step(a-3)+step(-3-a))'                \
    -prefix  ${opref}_preB.nii.gz

${prog}                                                      \
    -echo_edu                                                \
    -out_domain  all                                         \
    -insetA      ${opref}_preA.nii.gz                        \
    -insetB      ${opref}_preB.nii.gz                        \
    -prefix      ${opref}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dSpaceTimeCorr
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

# make a quick+small mask (sphere around xyz origin), because this
# prog is computationally intense --> slow
3dcalc                                                       \
    -echo_edu                                                \
    -a       mask_DWI+orig.HEAD                              \
    -expr    'step(100-(x-0)*(x-0)-(y-0)*(y-0)-(z-0)*(z-0))' \
    -prefix  ${opref}_MASK.nii.gz


${prog}                                                      \
    -echo_edu                                                \
    -insetA   REST_in_DWI.nii.gz'[5..15]'                    \
    -insetB   REST_in_DWI.nii.gz'[25..35]'                   \
    -mask     ${opref}_MASK.nii.gz                           \
    -prefix   ${opref}

if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------

set prog  = 3dZipperZapper
set opref = ${testdir}/o.${prog}

echo "++ test-run: ${prog}"

${prog}                                                      \
    -echo_edu                                                \
    -input   AVEB0_DWI.nii.gz'[0..10]'                       \
    -mask    mask_DWI+orig.HEAD                              \
    -prefix  ${opref}                                        \
    -do_out_slice_param
 
if ( ${status} ) printf "${prog}\n" >> ${otext}

# -------------------------------------------------------------------------
# -------------------------------------------------------------------------
# -------------------------------------------------------------------------

set nfail_status = `cat ${otext} | wc -l`

echo ""
echo ""
echo "---------------------------------------------------------"
echo "                         DONE"
echo ""
echo ""
if ( ${nfail_status} ) then
    echo "** Number of progs that failed status:  ${nfail_status}"
    cat ${otext}
else
    echo "++ No programs had failure status :)"
endif
echo ""
echo "---------------------------------------------------------"