AFIDS_afni_warps/AFIDS_template_xalign.csh

#!/bin/tcsh
# AFIDS_template_xalign.csh
# make swarm script for SLURM processing
#

# list of templates to align to each other
set template_list =  (   NMT_v2.0_sym_SS.nii.gz \
                         NMT_v2.1_asym_SS.nii.gz \
                         NMT_1.3_SS.nii.gz      \
                         D99.nii.gz    \
                         inia19.nii    \
                         yerkes19.nii.gz \
                         macMNI_rescale.nii.gz \
)

# some short names to match the list of templates in order
set template_abbrev_list = ( NMTv2sym NMTv2asym NMTv1.3 D99 inia19 Yerkes19 MNImac )


set template_index = 1

# remove previous swarm script
rm aw_all_cmds.swarm

# warp all templates to all the other templates
# avoid duplication by not repeating previous templates
foreach template ( $template_list )
   # make the base to align to start at the next in the list
   set templatebase_index = `ccalc -int "$template_index+1" `
   foreach templatebase ( ${template_list[${templatebase_index}-]} )
      set aw_cmd = "@animal_warper -ok_to_exist \
                      -base $templatebase \
                      -base_abbrev ${template_abbrev_list[$templatebase_index]}  \
                      -input ${template_list[$template_index]}      \
                      -input_abbrev ${template_abbrev_list[$template_index]}  \
                      -outdir aw_${template_abbrev_list[$template_index]}_to_${template_abbrev_list[$templatebase_index]}"
      echo $aw_cmd >> aw_all_cmds.swarm

      @ templatebase_index ++
   end
   @ template_index ++
end